Shaos
(journeyman)
2002/06/11 13:02
|
256-color backrground (see TETRIS)
| 
| |
; BACK_SP.A - Alexander Shabarshin 31.05.2002
; Loading background in .sh0 format:
; size 82944 bytes:
; 1024 bytes - palette (256 colors B,G,R,0)
; 320*256=81920 bytes of indexed image
; y=255..0
; x=0..319
back_sp:
ld hl,name_
ld c,11h
ld a,1
rst 10h
jp c,any_error
ld (handle_),a
ld c,13h
ld a,(handle_)
ld de,1024
ld hl,pal_
rst 10h
jp c,any_error
ld c,0A4h
ld hl,pal_
ld e,0
ld d,0
ld b,0FFh
ld a,0
rst 8h
in a,(0E2h)
ld (oldwin_),a
ld a,50h
out (0E2h),a
ld a,0
loopi:
dec a
out (89h),a
push af
ld c,13h
ld a,(handle_)
ld de,320
ld hl,0C000h
rst 10h
pop af
jp c,any_error
or a
jp nz,loopi
ld c,12h
ld a,(handle_)
rst 10h
jp c,any_error
ld a,(oldwin_)
out (0E2h),a
any_error:
ret
oldwin_ db 0
handle_ db 0
name_ db "backgrnd.sh0",0
pal_ ds 1024
Alexander Shabarshin (shaos@mail.ru)
|
Shaos
(enthusiast)
2002/10/10 08:53
|
Re: 256-color backrground (see TETRIS) 
[re: Shaos] |
| |
; BACK_SP.A - Alexander Shabarshin (shaos@mail.ru)
; http://shaos.ru/nedopc/sprinter.htm
; 31.05.2002 - first slow version
; 09.10.2002 - second fast version
; Loading background in .sh0 format:
; size 82944 bytes:
; 1024 bytes - palette (256 colors B,G,R,0)
; 320*256=81920 bytes of indexed image
; y=255..0
; x=0..319
back_sp:
ld hl,name_
ld c,11h
ld a,1
rst 10h
jr c,any_error_
ld (handle_),a
ld c,13h
ld a,(handle_)
ld de,1024
ld hl,pal_
rst 10h
jr c,any_error_
ld c,0A4h
ld hl,pal_
ld e,0
ld d,0
ld b,0FFh
ld a,0
rst 8h
in a,(0E2h)
ld (oldwin_),a
ld a,50h
out (0E2h),a
ld a,0
loopi_:
push af
ld c,13h
ld a,(handle_)
ld de,1280
ld hl,pal_
rst 10h
pop af
jr c,any_error_
ld bc,160
ld hl,pal_
ld d,4
loopo_:
push de
dec a
out (89h),a
ld de,0C000h
call acopy_160_
add hl,bc
ld de,0C0A0h
call acopy_160_
add hl,bc
pop de
dec d
jr nz,loopo_
or a
jr nz,loopi_
ld c,12h
ld a,(handle_)
rst 10h
jr c,any_error_
ld a,(oldwin_)
out (0E2h),a
any_error_:
ld a,#FF
out (89h),a
ret
acopy_160_:
push af
di
ld d,d
ld a,160
ld b,b
ld l,l
ld a,(hl)
ld (de),a
ld b,b
ei
pop af
ret
oldwin_ db 0
handle_ db 0
name_ db "backgrnd.sh0",0
pal_ ds 1280
Alexander Shabarshin (shaos@mail.ru)
http://www.shaos.ru
|
|
